Lógica de Programação – Estrutura de Repetição PARA – 15

Lógica de Programação - Estrutura de Repetição PARA

Prosseguindo nosso estudo sobre estruturas de repetição em lógica de programação, abordaremos nesta lição a estrutura PARA.

O comando PARA permite construir estruturas de loop para casos onde se conhece de antemão o número de repetições que devem ser realizadas (ou seja, número finito de laços). Por exemplo, quando sabemos de antemão que o laço deve se repetir 10 vezes; portanto, neste caso podemos usar a estrutura para.

Caso não haja como saber previamente o número de repetições necessárias, use preferencialmente as estruturas de repetição enquanto ou repita até.

Sintaxe do para

para variável de inicio até fim passo incremento faça
    instruções
fimpara

Onde: 

  • variável = variável contadora
  • início = valor inicial atribuído à variável
  • fim = valor final que a variável armazenará
  • incremento = valor para incrementar variável a cada loop (valor padrão: 1)

A figura seguinte ilustra a operação do laço para:

Fluxograma do laço para em lógica de programação

Exemplo

Imprimir na tela os números de 1 a 10, desta vez usando a estrutura de repetição "para".

var
    contador: inteiro
início
    para contador de 1 ate 10 passo 1 faca
      escreva (contador)
    fimpara
fimalgoritmo

O fluxograma a seguir mostra o funcionamento deste código:

Exercício de laço para em lógica de programação

 

Exercícios Resolvidos

1. Crie um programa que imprima na tela a mensagem "Bom dia" 15 vezes, usando o laço para.

Var
cont: inteiro
Inicio
para cont de 1 ate 15 faca
   escreval("Bom dia!")
fimpara
fimalgoritmo


2. Modifique o programa anterior para que ele pergunte o nome do usuário e então imprima a mensagem "Bom dia, NOME!" 20 vezes (o mesmo nome).

Var
cont: inteiro
nome: caractere
Inicio
escreval("Digite seu nome:")
leia(nome)
para cont de 1 ate 20 faca
   escreval("Bom dia " + nome + "!")
fimpara
fimalgoritmo

3. Crie um algoritmo que imprima na tela a sequência descendente de números entre 100 e 10.

Var
cont: inteiro
Inicio
para cont de 100 ate 10 passo -1 faca
   escreval(cont)
fimpara
fimalgoritmo

4. Crie um algoritmo que mostre a sequência de números entre 0 e um número qualquer digitado pelo usuário (pedir para o usuário digitar um número maior que zero, mas sem realizar validação).

Var
cont, num: inteiro
Inicio
escreval("Digite um número maior que zero:")
leia(num)
para cont de 0 ate num faca
   escreval(cont)
fimpara
fimalgoritmo

5. Modifique o programa anterior para que exiba uma sequência de números entre 10 e um número qualquer digitado pelo usuário, que seja maior do que 10. O programa deve mostrar mensagem de erro caso o número escolhido seja igual ou menor a 10.
Dica: usar validação com SE.

Var
cont, num: inteiro
Inicio
escreval("Digite um número maior que dez:")
leia(num)
se (num > 10) entao
   para cont de 10 ate num faca
      escreval(cont)
   fimpara
senao
   escreval("Número digitado não é maior que 10")
fimse
fimalgoritmo

6. Escreva um programa que mostre na tela a soma total da sequência de números 1 + 1/2 + 1/3 + ... + 1/20.
Mostrar o resultado com quatro casas decimais.

Var
cont: inteiro
soma: real
Inicio
soma <- 0
para cont de 1 ate 20 faca
   soma <- soma + (1 / cont)
fimpara
escreval("O total da soma das frações é ", soma:6:4)
Fimalgoritmo

7. Escreva um programa que mostre na tela a tabuada de um número qualquer escolhido pelo usuário.
A tabuada consiste nos resultados das multiplicações do número escolhido pelos números de 1 até 10.
Obs.: Caso o usuário entre com o valor 0 (zero), deve ser exibida uma mensagem de erro, em vez do cálculo da tabuada.

Var
cont: inteiro
num: inteiro
Inicio
escreval("Digite um número para mostrar sua tabuada:")
leia(num)
escreval()
se (num = 0) entao
   escreval("Número não pode ser zero")
senao
   escreval("Tabuada do", num, ":")
   para cont de 1 ate 10 faca
      escreval(cont, " x ", num, " = ", cont*num)
   fimpara
fimse
fimalgoritmo

É isso aí! Para uma explicação mais detalhada sobre a estrutura de repetição para, e para mais exemplos resolvidos, assista ao vídeo a seguir, do canal do YouTube da Bóson Treinamentos em Tecnologia:

Anterior: Estrutura de Repetição repita até

 

Sobre Fábio dos Reis (1250 Artigos)
Fábio dos Reis trabalha com tecnologias variadas há mais de 25 anos, tendo atuado nos campos de Eletrônica, Telecomunicações, Programação de Computadores e Redes de Dados. É um entusiasta de Unix, Linux e Open Source em geral, adora Eletrônica e Música, e estuda idiomas, além de ministrar cursos e palestras sobre diversas tecnologias em São Paulo e outras cidades do Brasil.
Contato: Website

2 Comentários em Lógica de Programação – Estrutura de Repetição PARA – 15

  1. Giovani Winter // 16/06/2014 em 7:10 // Responder

    Excelente treinamento. O conteúdo completo e de fácil entendimento. Parabéns a equipe.

Escreva um comentário

Seu e-mail não será divulgado


*