Tweet

Lógica de Programação – Estruturas de Repetição (Loop) – ENQUANTO

Em muitos casos é necessário repetir um trecho de um programa diversas vezes. Nesse caso podemos usar um “loop” que efetue essa repetição de código quantas vezes forem necessárias.

Os loops são chamados também de laços de repetição. Existem várias estruturas que podem ser utilizadas para criar loops em programação. Nesta lição iremos estudar a estrutura Enquanto.

Estrutura de Repetição Enquanto

• Essa estrutura realiza um teste lógico no início do loop, e cada vez que o teste retorna o valor verdadeiro, os comandos associados ao laço são executados.
• Quando o teste retornar falso, o laço é encerrado e o processamento volta para o fluxo principal do programa.

Sintaxe:

enquanto (condição_verdadeira) faça
    instruções executadas enquanto condição testada for verdadeira
fimenquanto

A ilustração a seguir mostra o funcionamento da estrutura de repetição enquanto:

Exemplo:

Vamos escrever um pequeno programa para imprimir na tela os números de 1 a 10, usando estrutura de repetição enquanto:

var
    num : inteiro
início
    num <- 1
    enquanto (num <= 10) faca
       escreval (num)
       num <- num + 1
    fimenquanto
fimalgoritmo

Ao executarmos esse programa, obteremos o seguinte resultado:

E a seguir temos o fluxograma que mostra o funcionamento deste programa de exemplo:

“Enquanto” o valor da variável num for menor ou igual a 10, será impresso na tela o valor dessa variável, e na sequência seu valor é incrementado pela instrução num <- num + 1.

Exxemplo 02

Crie um programa que “cadastre” e imprima na tela em forma de relatório os seguintes dados das disciplinas de uma escola:

• nome da disciplina
• número de alunos matriculados
• frequência de aprovação
• nota mínima para aprovação do aluno

O programa deve permitir entrar com esses dados para quantas disciplinas for desejado, e deve ser encerrado ao ser digitada a palavra fim.

Resolução

Algoritmo "Cadastro de Disciplinas"
// Disciplina : Lógica de Programação 
// Professor : Fábio dos Reis 
// Data atual : 19/07/2018

Var
nome:caractere
numAlunos, freq: inteiro
nota: real

Inicio
escreval("Digite o nome da disciplina, ou fim para encerrar:")
leia(nome)

enquanto (nome <> "fim") faca
    escreval("Entre com o número de alunos:")
    leia(numAlunos)
    escreval("Digite a frequência da disciplina:")
    leia(freq)
    escreval("Digite a nota mínima:")
    leia(nota)

    // Gerando o Relatório:
    escreval()
    escreval("---------------------------------")
    escreval("Disciplina: " + nome)
    escreval("Número de Alunos: ", numAlunos)
    escreval("Frequência mínima: ", freq)
    escreval("Nota para aprovação: ", nota)
    escreval("---------------------------------")
    escreval()
    // Fim do Relatório

    escreval("Digite o nome da disciplina, ou fim para encerrar:")
    leia(nome)
fimenquanto
Fimalgoritmo

É isso aí! Para uma explicação mais detalhada sobre a estrutura de repetição enquanto, e para mais exemplos resolvidos, assista ao vídeo a seguir, do canal do YouTube da Bóson Treinamentos em Tecnologia:

Anterior: Desvio Condicional Aninhado

Próximo: Estrutura de Repetição Repita .. Até